ESP8266 Range Finder using HC-SR04 and PCF8574AP LCD

Overview 

The HC-SR04 is an ultra-sonic range finder. It use sound wave at the speed of 340m/s that travel in air to measure any detected obstacle. That sound wave signal will travels back whenever there is a barrier created by any object. It uses a speaker that propagates an ultra-sonic signal that human ears could not hear. The detector is a microphone circuit that has an amplifier. The distance of the detected object is the time the sound wave travel divides by 2. The measurement formula is,

Test distance = (high level time * velocity of sound ) / 2.

The velocity of sound is 340m/s. 

 

Distance Measurement

 

The table below summarizes the features of the HC-SR04 Distance Sensor.

HC-SR04 Parameters

 This Arduino module is very popular because of its low cost, easy-to-use, etc.

The Arduino HC-SR04 Module

The Arduino HC-SR04 Module

 

The high level time is the input high time creates by the echo pin of the HC-SR04 Ultra-Sonic Range Finder Module. That time duration is measure in micro-seconds, and the Test distance is measure in cm. To measure that time duration, the micro-controller need to process it precisely. In Arduino, it has the pulseIn function that can measure any logic level ( HIGH or LOW) time at any specific input pins. 

ESP8266 Interfaces with the PCF8574AP and HC-SR04 

In this example, I use the HC-SR04 to measure the distance. The result will show on a 16x2 character LCD controlled by the PCF8574AP I/O expansion chip. Because the ESP-12E has a limited of digital I/O pins. On the other hands, Some pins of this IoT module are connected to other peripherals. 

The 7-bit Arduino slave address of the PCF8574AP here is 0x38. Commonly they use the PCF8574T Arduino Two-Wire LCD module that has different slave address.

Circuit Connection

It needs a small breadboard to build the circuit. Connect the all components as follow.

• Connection between ESP-12E and HC-SR04

HC-SR04	ESP12-E
« 1 2 3 4 »
VIN	VCC
Trig	D6 (GPIO 12)
Echo	D5 (GPIO 14)
GND	GND

• Connection between ESP-12E and PCF8574AP LCD

ESP-12E	PCF8574AP LCD
« 1 2 3 4 »
GND	GND
D1 (GPIO 12)	SCL
D2 (GPIO 14)	SDA
VIN	VCC

ESP8266 Arduino Source Code

I use the Arduino LiquidCrystal_I2C library. It's originally developed to work with the Arduino AVR. However for the ESP8266, it is compatible. It works fine.

#include <Wire.h> 
#include <LiquidCrystal_I2C.h>

LiquidCrystal_I2C lcd(0x38,16,2); 

#define trigPin D6
#define echoPin D5

/*
PWM OUTPUT 0-25000uS in which 1cm=50uS
*/
long   duration;
int   distance;

void setup() {
  pinMode(trigPin,OUTPUT);
  pinMode(echoPin,INPUT);
  lcd.init();
  // Print a message to the LCD.
  lcd.backlight();
  lcd.clear();
  lcd.setCursor(0,0);
  lcd.print("ESP-12E PCF8574AP");
  lcd.setCursor(0,1);
  lcd.print("and HC-SR04");
  delay(10000);
  lcd.clear();
}

void loop() {
  digitalWrite(trigPin,LOW);
  delayMicroseconds(7);
  // Set the trigPin high for 10 uS
  digitalWrite(trigPin,HIGH);
  digitalWrite(trigPin,HIGH);
  delayMicroseconds(10);
  digitalWrite(trigPin,LOW);
  duration=pulseIn(echoPin,HIGH);
  // Calculation for distance
  if(duration<=25000)
  distance = duration * 0.034 / 2;
  else
  distance=0;
  lcd.setCursor(0,0);
  lcd.print("Time: " + String(duration) + "uS  ");
  lcd.setCursor(0,1);
  lcd.print("Distance: " + String(distance) + "cm  ");  
  delay(500);
}

 

 

Pictures

I can not find these module at any online circuit simulator now. Currently WOKWI only support some high-end board. 

 

Distance Measurement

 

 

ESP8266 DHT-11 Sensor and SH1106 OLED Interfacing

Overview 

The DHT-11 is a environmental sensor capable of converting surrounding temperature and humidity. It is a digital sensor, implementing the One-Wire communication protocol. The master micro-controller just need on digital I/O pin to command and get sensor data from this device. Its One-Wire data packet is very easy decode using a simple 8-bit micro-controller. The data packet is 40-bit or 5 bytes, containing two bytes of temperature data, two bytes of humidity data, and one byte of error correction.

 

Sensor Data Reading

This sensor is very low cost, widely available. It's popular among Arduino users, mini projects, etc. Using this sensor in agricultural or home garden is very popular. However it is not durable due to surrounding environment.

 

Arduino DHT Sensor Library

Adafruit has a lot of libraries and examples for their products. However I didn't buy any products. Some sensor are compatible in software. Install the DHT sensor library and open its example, DHTTester.ino sketch as shown below.

 

Open the DHTTester.ino Sketch

 This example the master MCU will read the environmental data from DHT sensor. It support DHT11, DTH-21, and DHT-22. However some pins of the ESP-12E board doesn't work with this sensor because they are connected to other devices or have alternative function such as TWI, UART, etc.

ESP8266 Interfaces with DHT-11 Sensor and SH1106 OLED 

I use this example, and added some OLED display function to read and display environmental data and the SH0016 124x64 OLED module. I use pin D3 of the ESP-12E module since other pin doesn't work with this one-wire sensor. You can test it by yourself.

It needs these libraries,

1.  DHT
2.  Wire
3.  Adafruit_GFX
4.  Adafruit_SH110X
5. Adafruit_Sensor 

Arduino Source Code

#include "DHT.h"
#include <Wire.h>
#include <Adafruit_GFX.h>
#include <Adafruit_SH110X.h>

#define i2c_Address 0x3c 
/*initialize with the I2C addr 0x3D 
Typically Adafruit OLED's */
//#define i2c_Address 0x3d 

#define SCREEN_WIDTH 128 
#define SCREEN_HEIGHT 64 
#define OLED_RESET -1   
Adafruit_SH1106G display = 
Adafruit_SH1106G
(SCREEN_WIDTH, SCREEN_HEIGHT, &Wire, OLED_RESET);

// Digital pin connected to the DHT sensor
#define DHTPIN D3     

#define DHTTYPE DHT11   // DHT 11

DHT dht(DHTPIN, DHTTYPE);

void setup() {
  // wait for the OLED to power up
  delay(250); 
  // Address 0x3C default
  display.begin(i2c_Address, true); 
  // Clear the buffer.
  display.clearDisplay();
  Serial.begin(9600);
  Serial.println(F("DHTxx test!"));

  dht.begin();

  display.setTextColor(SH110X_WHITE);
  display.setCursor(0, 8);
  display.setTextSize(3);
  display.println("ESP8266");
  display.println("NodeMCU");
  display.display();
  delay(5000);
  display.clearDisplay();
  
  display.setCursor(0, 0);
  display.setTextSize(3);
  display.println("SH1106");
  display.println("OLED");
  display.display();
  delay(5000);
  display.clearDisplay();

  display.setCursor(10, 8);
  display.setTextSize(3);
  display.println("DHT-11");
  display.println("Sensor");
  display.display();
  delay(5000);
  display.clearDisplay();
}

void loop() {
  // Wait a few seconds between measurements.
  delay(2000);

  /* Reading temperature or humidity takes 
  about 250 milliseconds!
   Sensor readings may also be up to 2 seconds 
   'old' (its a very slow sensor)*/
  float h = dht.readHumidity();
  // Read temperature as Celsius (the default)
  float t = dht.readTemperature();
  // Read temperature as Fahrenheit (isFahrenheit = true)
  float f = dht.readTemperature(true);

  // Check if any reads failed and exit early (to try again).
  if (isnan(h) || isnan(t) || isnan(f)) {
    Serial.println(F("Failed to read from DHT sensor!"));
    return;
  }

  // Compute heat index in Fahrenheit (the default)
  float hif = dht.computeHeatIndex(f, h);
  // Compute heat index in Celsius (isFahreheit = false)
  float hic = dht.computeHeatIndex(t, h, false);

  Serial.print(F("Humidity: "));
  Serial.print(h);
  Serial.print(F("%  Temperature: "));
  Serial.print(t);
  Serial.print(F("°C "));
  Serial.print(f);
  Serial.print(F("°F  Heat index: "));
  Serial.print(hic);
  Serial.print(F("°C "));
  Serial.print(hif);
  Serial.println(F("°F"));

  display.clearDisplay();
  delay(1500);
  // Clear the buffer.
  display.clearDisplay();
  display.setTextColor(SH110X_WHITE);
  display.setCursor(32, 0);
  display.setTextSize(2);
  display.println("Temp:");
  display.println("   " + String(t) + "C");
  display.setCursor(0, 32);
  display.println(" Humidity:");
  display.println("   " + String(h) + "%");
  display.display();
}

Connection

Connect all components as follow,

1. SH1106 OLED 

Table 1: ESP-12E and SH1106 Connection

1.  DHT-11 Sensor

Table 2: ESP-12E and DHT-11 Connection

Picture

I tested it using my DIY ESP8266 TWI Communication Board.

 

ESP8266 Interfaces with DHT-11 Sensor and SH1106 OLED 

ESP8266 Interfaces with DHT-11 Sensor and SH1106 OLED 

Video

 

I keep the video on YouTube. 

 

 

 

 

 

 

 

 

 

 

 

ESP8266 TWI SH1106 and DS18B20 Temperature Sensor

The DS18B20 is a digital thermometer able to converts surrounding temperature between -55°C and +125°C. It operates between 3.0VDC to 5.5VDC which is suitable for hobbyist and industrial applications. It implements the One-Wire digital communication protocol, requires only one bi-directional I/O pin for data and command transmission or reception. Its ROM Search feature allow multiple DS18X20 sensors to connect on a single wire bus.

 

Temperature Reading via ESP8266 D0 Pin

Commanding and decoding data from this sensor is easy. The manufacturers offer a lot of example programs written in Assembly or C language. For Arduino users, there are a lot of libraries available, created by various authors.

Using Arduino IDE, we can use this sensor from scratch by installing some related libraries. I use the  OneWire and DallasTemperature library. Because its C++ function is easily readable and short. Go into the DallasTemprature and open the simple.ino file. To test this sensor and see the result over serial port.

 

Arduino simple.ino Sketch

 

However I modify this example to work with a 128x64 OLED display, SH1106. So it needs these libraries:

1. OneWire
2.  DallasTemperature
3.  Wire
4.  Adafruit_GFX
5.  Adafruit_SH110X

In this example, the ESP-12E read temperature data from a single DS18B20 connects to D0 pin. The result will show on the SH1106 OLED display.

DS18B20 Pin Configurations

 

There are many device packages for this sensor. For hobbyists, it's suitable to use a transistor-like TO-92 package. However, there are some Arduino modules for this sensor available at very low cost. That's below 1USD.

Its DQ or data pin is open-drain. So we need to add a weak pull up resistor between 4.7kΩ and 10kΩ depending on its range.
 

ESP8266 Arduino Source Code:

// Include the libraries we need
#include <OneWire.h>
#include <DallasTemperature.h>

/* Data wire is plugged into 
port 2 on the Arduino */
#define ONE_WIRE_BUS D0

/* Setup a oneWire instance to communicate 
with any OneWire devices 
(not just Maxim/Dallas temperature ICs) */
OneWire oneWire(ONE_WIRE_BUS);

/* Pass our oneWire reference 
to Dallas Temperature. */
DallasTemperature sensors(&oneWire);

// OLED Section
#include <Wire.h>
#include <Adafruit_GFX.h>
#include <Adafruit_SH110X.h>

/* Uncomment the initialize the I2C address , 
uncomment only one, If you get a totally blank 
screen try the other*/
#define i2c_Address 0x3c 
/*initialize with the I2C addr 0x3D 
Typically Adafruit OLED's */
//#define i2c_Address 0x3d 

#define SCREEN_WIDTH 128 
#define SCREEN_HEIGHT 64 
#define OLED_RESET -1   
Adafruit_SH1106G display = 
Adafruit_SH1106G(SCREEN_WIDTH, SCREEN_HEIGHT, &Wire, OLED_RESET);
/*
 * The setup function. We only start the sensors here
 */
void setup(void)
{
  // start serial port
  Serial.begin(9600);
  Serial.println("Dallas Temperature IC Control Library Demo");

  // Start up the library
  sensors.begin();

  delay(250); // wait for the OLED to power up
  display.begin(i2c_Address, true); // Address 0x3C default
  // Clear the buffer.
  display.clearDisplay();
 
  display.setTextColor(SH110X_WHITE);
  display.setCursor(0, 8);
  display.setTextSize(3);
  display.println("ESP8266");
  display.println("NodeMCU");
  display.display();
  delay(5000);
  display.clearDisplay();
  
  display.setCursor(10, 8);
  display.setTextSize(3);
  display.println("SH1106");
  display.println("  OLED");
  display.display();
  delay(5000);
  display.clearDisplay();

  display.setCursor(10, 8);
  display.setTextSize(3);
  display.println("Temp");
  display.println("Sensor");
  display.display();
  delay(5000);
  display.clearDisplay();
}

/*
 * Main function, get and show the temperature
 */
void loop(void)
{
  
  Serial.print("Requesting temperatures...");
  sensors.requestTemperatures(); 
  Serial.println("DONE");
  delay(1500);
  
  float tempC = sensors.getTempCByIndex(0);

  // Check if reading was successful
  if (tempC != DEVICE_DISCONNECTED_C)
  {
    Serial.print("Temperature for the device 1 (index 0) is: ");
    Serial.println(tempC);
  }
  else
  {
    Serial.println("Error: Could not read temperature data");
  }
  display.setTextColor(SH110X_WHITE);
  display.setCursor(16, 0);
  display.setTextSize(2);
  display.println("Temp (C):");
  display.setCursor(16, 32);
  display.setTextSize(3);
  display.println(tempC);
  display.display();
  delay(900);
  // Clear the buffer.
  display.clearDisplay();
  
}

Pictures:

I use my own ESP8266 TWI Prototype Board to test this example.

 

ESP8266 TWI Prototype Board

 

ESP8266 TWI Prototype Board

 

ESP8266 TWI Prototype Board

 Video:

 

 

 

ESP8266 TWI and SH1106 DS1307 RTC

In this example, I use the TWI module of the ESP8266 to interfaces with the SH1106 128x64 OLED and the DS1307 Real Time Clock (RTC) chip. The SH0016 OLED and the DS1307 RTC chip share the same pins on a single TWI bus. The TWI pins of the ESP8266 are, SCL (D0) and SDA (D1).

 

 

 

ESP8266 Arduino Source Code:

I use the Adafruit_SH110X, Adafruit_GFX, Wire, and RtcDs1307 library. 

#include <SPI.h>
#include <Wire.h>
#include <Adafruit_GFX.h>
#include <Adafruit_SH110X.h>
#include <RtcDS1307.h>
RtcDS1307<TwoWire> Rtc(Wire);

//initialize with the I2C addr 0x3C Typically eBay OLED's
#define i2c_Address 0x3c 
//initialize with the I2C addr 0x3D Typically Adafruit OLED's
//#define i2c_Address 0x3d 

#define SCREEN_WIDTH 128 // OLED display width, in pixels
#define SCREEN_HEIGHT 64 // OLED display height, in pixels
#define OLED_RESET -1   //   QT-PY / XIAO
Adafruit_SH1106G display = 
Adafruit_SH1106G(SCREEN_WIDTH, SCREEN_HEIGHT, &Wire, OLED_RESET);

bool wasError(const char* errorTopic = "")
{
    uint8_t error = Rtc.LastError();
    if (error != 0)
    {
        // we have a communications error
        // see https://www.arduino.cc/reference/en/language/functions/communication/wire/endtransmission/
        // for what the number means
        Serial.print("[");
        Serial.print(errorTopic);
        Serial.print("] WIRE communications error (");
        Serial.print(error);
        Serial.print(") : ");

        switch (error)
        {
        case Rtc_Wire_Error_None:
            Serial.println("(none?!)");
            break;
        case Rtc_Wire_Error_TxBufferOverflow:
            Serial.println("transmit buffer overflow");
            break;
        case Rtc_Wire_Error_NoAddressableDevice:
            Serial.println("no device responded");
            break;
        case Rtc_Wire_Error_UnsupportedRequest:
            Serial.println("device doesn't support request");
            break;
        case Rtc_Wire_Error_Unspecific:
            Serial.println("unspecified error");
            break;
        case Rtc_Wire_Error_CommunicationTimeout:
            Serial.println("communications timed out");
            break;
        }
        return true;
    }
    return false;
}

void setup()   {
  Rtc.Begin();
  #if defined(WIRE_HAS_TIMEOUT)
    Wire.setWireTimeout(3000 /* us */, true /* reset_on_timeout */);
  #endif

  RtcDateTime compiled = RtcDateTime(__DATE__, __TIME__);
  if (!Rtc.IsDateTimeValid()) 
    {
        if (!wasError("setup IsDateTimeValid"))
        {
            // Common Causes:
            //    1) first time you ran and the device wasn't running yet
            //    2) the battery on the device is low or even missing

            Serial.println("RTC lost confidence in the DateTime!");
            // following line sets the RTC to the date & time this sketch was compiled
            // it will also reset the valid flag internally unless the Rtc device is
            // having an issue

            Rtc.SetDateTime(compiled);
        }
    }

    if (!Rtc.GetIsRunning())
    {
        if (!wasError("setup GetIsRunning"))
        {
            Serial.println("RTC was not actively running, starting now");
            Rtc.SetIsRunning(true);
        }
    }

    RtcDateTime now = Rtc.GetDateTime();
    if (!wasError("setup GetDateTime"))
    {
        if (now < compiled)
        {         
            Rtc.SetDateTime(compiled);
        }
        
    }

  delay(250); // wait for the OLED to power up
  display.begin(i2c_Address, true); // Address 0x3C default
 //display.setContrast (0); // dim display
 
  // Clear the buffer.
  display.clearDisplay();

  // text display tests
  display.setTextSize(2);
  display.setTextColor(SH110X_BLACK, SH110X_WHITE); // 'inverted' text
  
  display.setCursor(0, 0);
  display.println("ESP8266");
  display.setTextColor(SH110X_WHITE);
  display.println("SH1106 LCD"); 
  display.println("and DS1307");
  display.println("RTC Chip");
  display.display();
  delay(5000);
  display.clearDisplay();
  display.display();
}


void loop() {
  display.clearDisplay();
    if (!Rtc.IsDateTimeValid()) 
    {
        if (!wasError("loop IsDateTimeValid"))
        {          
          display.setCursor(0, 0);
          display.println("RTC lost confidence in the DateTime!");
          display.display();
        }
    }

    RtcDateTime now = Rtc.GetDateTime();
    if (!wasError("loop GetDateTime"))
    {
        printDateTime(now);
        
    }
    delay(500); 
}

#define countof(a) (sizeof(a) / sizeof(a[0]))

void printDateTime(const RtcDateTime& dt)
{
    char datestring[26];

    snprintf_P(datestring, 
            countof(datestring),
            PSTR("%02u/%02u/%04u %02u:%02u:%02u"),
            dt.Month(),
            dt.Day(),
            dt.Year(),
            dt.Hour(),
            dt.Minute(),
            dt.Second() );
    
    display.setCursor(0, 0);
    display.println("Date:");
    display.println(String(dt.Year()) + "/" + String(dt.Month()) + "/" + String(dt.Day()));
    display.println("Time:"); 
    display.println(String(dt.Hour()) + ":" + String(dt.Minute()) + "/" + String(dt.Second()));
    display.display();
}

 In Arduino, It also has a software TWI library. So if these two pins are in used with other devices. We can select other digital pins.

Pictures

I tested this example on my DIY ESP8266 TWI Board.

My DIY ESP8266 TWI Board

My DIY ESP8266 TWI Board